Excel'de sayıyı yazıya dönüştürme

28 Oct 2025 16:00

Ort. 2 dk.

Neden Excel'de kendi içinde sayıyı okunuşuna dönüştürme fonksiyonu yok bilmiyorum, bu yüzden faydalı olması amacıyla kendimkini yazdım.

Aslında çeşitli forumlarda bu şekilde kendi formüllerini oluşturup paylaşanlar hep var. Fakat denk geldiğim çözümler, genel olarak yalın fonksiyonlarla yazılmaktan ziyade Visual Basic makroları ile yazılmıştı. Bu da benim aradığım bir şey değil, çünkü makrolar yalnızca Excel'in masaüstü sürümlerinde kullanılabiliyor, ve üstelik kod çalıştırmaya olanak sağladığından dolayı Office sürümlerinde varsayılan olarak makrolar kapalı şekilde gelebiliyor, ve/ya makro içeren bir dosya açtığınızda çeşitli uyarılar çıkartabiliyor.

Bu yüzden bütün işlemleri yine yalnızca Excel içinde yapmak taşınabilirlik açısından çok daha iyi olacak.

Mantık basit. Sayıları her binlik basamakta bir ayırıp, elde oluşan üçlü rakam grupları için 0'dan 9'a kadar sıralanmış yazı karşılığına dönüştürmek gerekiyor.

001 654 243 → bir milyon altı yüz elli dört bin iki yüz kırk üç
─┬─ ─┬─ ─┬─
 │   │   │
 │   │   │
 │   │   └─ → iki yüz kırk üç
 │   │
 │   └───── → altı yüz elli dört = bin
 │
 └───────── → bir                = milyon

Aynı işlemi her binlik basamak için tekrar etmemiz gerektiğinden, 1000'in kuvvetini artırarak istediğimiz kadar da uzatabiliriz.

Örneğin A1 hücresinde 2147654243 yazıyorsa, aşağıdaki formülle 1000 sayısının 2. kuvvetindeki kısmı (1000 ^ 2), yani sadece "milyon"lar basamaklarını alabiliriz, bu da 147 eder:

=MOD(TAMSAYI(MUTLAK(A1) / KUVVET(1000; 2)); 1000)

Daha sonradan üç basamağa düşürdüğümüz bu sayıyı, içinde kaç yüzlük, kaç onluk ve kaç birlik olduğu şeklinde ayırabiliriz.

=TAMSAYI(A2 / 100) & " yüzlük " & MOD(TAMSAYI(A2 / 10); 10) & " onluk " & MOD(TAMSAYI(A2); 10) & " birlik "

Fakat burada hesaba katmamız gereken özel durumlar da var.

Örneğin, 1000000 sayısını hep "bir milyon" olarak okusak da 1000 sayısına hiçbir zaman "bir bin" demeyiz, sadece "bin" deriz. Bu 100 için de geçerli, hiçbir zaman "bir yüz" olarak okunmuyor. O yüzden bu basamaklar için ayrı işlem yapılması gerekiyor.

Ayrıca aynı hesaplamayı her binlik basamakta bir tekrarlamamız gerektiğinden, aynı basamak bölme işlemine de birden fazla kez ihtiyacımız olacak. Excel'in yeni sürümlerindeki LAMBDA işlevi kullanarak formülün içinde yeniden kullanılabilir özel bir işlev oluşturarak bütün formülü çok daha kısa tutabiliyoruz. Ancak çoğu yerde hala Excel'in eski sürümleri kullanıldığı için aynı formülün LAMBDA içermeyen versiyonuna da sahip olmamız iyi olur.

Tüm bu durumlar ele alındığında, aşağıdaki formül yeterli olacaktır:

Bu formül yalnızca Türkçe dilinde ve bölgesel ayarı Türkiye olarak ayarlanan Excel'de çalışır. Excel'deki işlev adları ve parametre ayırıcıları bölgeye göre farklılık gösterir. Örneğin İngilizce dilindeyseniz =SUM(A1, 0.45, A2) yazmanız gerekiyorken, Türkçe'de ise yalnızca =TOPLA(A1; 0,45; A2) çalışır. Başka bir dilde yazılmış bir fonksiyonu kullanmanız için önce o dildeki Excel'den dosyaya kaydedilmesi gerekiyor. Bunu yapmak için Office'in web sürümünü de kullanabilirsiniz.

Excel Web, Excel 2024 ve sonrasıLAMBDA işlevi kullanmadan (Excel 2021 ve sonrası)

=LET(
    _CELL; A1; // Hücrenin referansını buradan değiştirin.
    _SPACE; " "; // Basamakların arasına eklenecek boşluk. Örneğin "beş yüz kırk altı" yerine "beşyüzkırkaltı" yazmasını istiyorsanız, bu boşluğu buradan silebilirsiniz.
    _PREFIX; ""; // Oluşan metnin en başına eklenecek bir ön ek. Örneğin "yalnız " olarak ayarlanırsa sonuç "yalnız beş yüz kırk altı" olur.
    _MONEY; DOĞRU; // Sayıyı "lira" ve "kuruş" şeklinde para biçimine dökmek istiyorsanız bunu DOĞRU yapın (154,20 -> "yüz elli dört lira yirmi kuruş" olur), eğer normal bir sayı olarak yalnızca ondalik kesime gelindiğinde "virgül" yazmasını istiyorsanız YANLIŞ yapın. (154,20 -> "yüz elli dört virgül yirmi")

    _DIGITS; LAMBDA(x; ELEMAN(x; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"));
    _TENS; LAMBDA(x; ELEMAN(x; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));

    _FROM_HUNDRED; LAMBDA(
        x; LET(
            hundreds; TAMSAYI(x / 100);
            tens; MOD(TAMSAYI(x / 10); 10);
            units; MOD(TAMSAYI(x); 10);
            METİNBİRLEŞTİR(
                _SPACE; DOĞRU;
                EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; _DIGITS(hundreds) & _SPACE) & "yüz");
                EĞER(tens = 0; ""; _TENS(tens));
                EĞER(units = 0; ""; _DIGITS(units))
            )
        )
    );

    _FROM_THOUSAND; LAMBDA(
        power; name; LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; power)); 1000);
            EĞER(count = 0; ""; EĞER(VE(power = 1; count = 1); name; _FROM_HUNDRED(count) & EĞER(name = ""; ""; _SPACE) & name))
        )
    );

    _FRACTIONS; LET(
        fractions; YUVARLA(MOD(MUTLAK(_CELL); 1) * 100; 0);
        EĞER(fractions = 0; ""; " " & EĞER(_MONEY; ""; "virgül" & " ") & _FROM_HUNDRED(fractions) & EĞER(_MONEY; " " & "kuruş"; ""))
    );

    _PREFIX & EĞER(_CELL < 0; "eksi" & " "; "") & METİNBİRLEŞTİR(
        _SPACE; DOĞRU;
        _FROM_THOUSAND(4; "trilyon"); // Bu formül 1000'in 4. kuvvetine kadar olan sayıları, yani trilyonları destekliyor. Bunun üzerine de çıkmanız gerekiyorsa buradaki gibi _FROM_THOUSAND çağrısına ekleme yapıp öndeki sayıyı 1 artırabilirsiniz.
        _FROM_THOUSAND(3; "milyar");
        _FROM_THOUSAND(2; "milyon");
        _FROM_THOUSAND(1; "bin");
        _FROM_THOUSAND(0; "")
    ) & EĞER(_MONEY; " " & "lira"; "") & _FRACTIONS
)

=LET(
    _CELL; A1; // Hücrenin referansını buradan değiştirin.
    _SPACE; " "; // Basamakların arasına eklenecek boşluk. Örneğin "beş yüz kırk altı" yerine "beşyüzkırkaltı" yazmasını istiyorsanız, bu boşluğu buradan silebilirsiniz.
    _PREFIX; ""; // Oluşan metnin en başına eklenecek yazı. Örneğin "yalnız " olarak ayarlanırsa sonuç "yalnız beş yüz kırk altı" olur.
    _MONEY; DOĞRU; // Sayıyı "lira" ve "kuruş" şeklinde para biçimine dökmek istiyorsanız bunu DOĞRU yapın (154,20 -> "yüz elli dört lira yirmi kuruş" olur), eğer normal bir sayı olarak yalnızca ondalik kesime gelindiğinde "virgül" yazmasını istiyorsanız YANLIŞ yapın. (154,20 -> "yüz elli dört virgül yirmi")

    _PREFIX & EĞER(_CELL < 0; "eksi" & " "; "") & METİNBİRLEŞTİR(
        _SPACE; DOĞRU;
        LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; 4)); 1000);
            EĞER(
                count = 0; ""; 
                LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                ) & _SPACE & "trilyon"
            )
        );LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; 3)); 1000);
            EĞER(
                count = 0; ""; 
                LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                ) & _SPACE & "milyar"
            )
        );LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; 2)); 1000);
            EĞER(
                count = 0; ""; 
                LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                ) & _SPACE & "milyon"
            )
        );LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; 1)); 1000);
            EĞER(
                count = 0; ""; EĞER(count = 1; "bin";
                LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                ) & _SPACE & "bin"
            ))
        );LET(
            count; MOD(TAMSAYI(MUTLAK(_CELL) / KUVVET(1000; 0)); 1000);
            EĞER(
                count = 0; ""; 
                LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                )
            )
        )) & EĞER(_MONEY; " " & "lira"; "") & LET(
            count; YUVARLA(MOD(MUTLAK(_CELL); 1) * 100; 0);
            EĞER(
                count = 0; ""; 
                " " & EĞER(_MONEY; ""; "virgül" & " ") & LET(
                    hundreds; TAMSAYI(count / 100);
                    tens; MOD(TAMSAYI(count / 10); 10);
                    units; MOD(count; 10);
                    METİNBİRLEŞTİR(
                        _SPACE; DOĞRU;
                        EĞER(hundreds = 0; ""; EĞER(hundreds = 1; ""; ELEMAN(hundreds; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz") & _SPACE) & "yüz");
                        EĞER(tens = 0; ""; ELEMAN(tens; "on"; "yirmi"; "otuz"; "kırk"; "elli"; "altmış"; "yetmiş"; "seksen"; "doksan"));
                        EĞER(units = 0; ""; ELEMAN(units; "bir"; "iki"; "üç"; "dört"; "beş"; "altı"; "yedi"; "sekiz"; "dokuz"))
                    )
                ) & EĞER(_MONEY; " " & "kuruş"; "")
            )
        )
)

ysfchn

ysfchn

Excel'de sayıyı yazıya dönüştürme